'From Squeak3.1alpha of 5 February 2001 [latest update: #3519] on 6 February 2001 at 9:45:43 am'!
"Change Set:		projLoading
Date:			6 February 2001
Author:			Bob Arning

Project loading fixes:
- when loading an old-style .project, try to set the project name and last directory.
- change String>>unescapePercents to return self if not really an escaped string"!


!ProjectLoading class methodsFor: 'as yet unclassified' stamp: 'RAA 2/6/2001 09:44'!
openFromFile: preStream fromDirectory: aDirectoryOrNil withProjectView: existingView
	"Reconstitute a Morph from the selected file, presumed to be represent a Morph saved via the SmartRefStream mechanism, and open it in an appropriate Morphic world."
 	| morphOrList proj newProj |

	ProgressNotification signal: '2:fileSizeDetermined ',preStream size printString.
	morphOrList _ preStream asUnZippedStream.
	preStream sleep.		"if ftp, let the connection close"
	ProgressNotification  signal: '3:unzipped'.
	morphOrList _ morphOrList fileInObjectAndCode.
	ProgressNotification  signal: '4:filedIn'.
	ProgressNotification  signal: '9999 about to enter project'.		"the hard part is over"
	(morphOrList isKindOf: ImageSegment) ifTrue: [
		proj _ morphOrList arrayOfRoots 
			detect: [:mm | mm class == Project] 
			ifNone: [^self inform: 'No project found in this file'].
		proj versionFrom: preStream.
		proj lastDirectory: aDirectoryOrNil.
		CurrentProjectRefactoring currentBeParentTo: proj.
		existingView ifNil: [
			Smalltalk isMorphic ifTrue: [
				proj createViewIfAppropriate.
			] ifFalse: [
				ProjectView openAndEnter: proj.
				"Note: in MVC we get no further than the above"
			].
		] ifNotNil: [
			(existingView project isKindOf: DiskProxy) ifFalse: [
				existingView project changeSet name: ChangeSet defaultName
			].
			"proj changeSet name: otherProjectName."	"<<< why would we need this?"
			(existingView owner isKindOf: SystemWindow) ifTrue: [
				existingView owner model: proj
			].
			existingView project: proj.
		].
		^ ProjectEntryNotification signal: proj
	].

	(morphOrList isKindOf: SqueakPage) ifTrue: [
		morphOrList _ morphOrList contentsMorph
	].
	(morphOrList isKindOf: PasteUpMorph) ifFalse: [
		^ self inform: 'This is not a PasteUpMorph or exported Project.'
	].

	[newProj _ Project newMorphicOn: morphOrList]
		on: ProjectViewOpenNotification
		do: [ :ex | ex resume: false].	
	(preStream respondsTo: #localName) ifTrue: [
		newProj changeSet name: (preStream localName copyUpTo: $.).
	].
	newProj
		lastDirectory: aDirectoryOrNil;
		enter

! !


!String methodsFor: 'internet' stamp: 'RAA 2/6/2001 09:37'!
unescapePercents
	"change each %XY substring to the character with ASCII value XY in hex.  This is the opposite of #encodeForHTTP"
	| ans c asciiVal pos oldPos specialChars |
	ans _ WriteStream on: String new.
	oldPos _ 1.
	specialChars _ '+%' asCharacterSet.

	[pos _ self indexOfAnyOf: specialChars startingAt: oldPos. pos > 0]
	whileTrue: [
		ans nextPutAll: (self copyFrom: oldPos to: pos - 1).
		c _ self at: pos.
		c = $+ ifTrue: [ans nextPut: $ ] ifFalse: [
			(c = $% and: [pos + 2 <= self size]) ifTrue: [
				asciiVal _ (self at: pos+1) asUppercase digitValue * 16 +
					(self at: pos+2) asUppercase digitValue.
				pos _ pos + 2.
				asciiVal > 255 ifTrue: [^self].	"not really an escaped string"
				ans nextPut: (Character value: asciiVal)]
			ifFalse: [ans nextPut: c]].
		oldPos _ pos+1].
	ans nextPutAll: (self copyFrom: oldPos to: self size).
	^ ans contents! !