'From Squeak3.1alpha of 5 February 2001 [latest update: #3546] on 8 February 2001 at 8:56:23 pm'!

!SystemDictionary methodsFor: 'housekeeping' stamp: 'di 11/8/2000 09:06'!
findNamesLikeGeorge: pName  "Smalltalk findNamesLikeGeorge: 'george'"
	"Will find personal names that perhaps don't belong in an official release."
	"sometimes finds much more, unfortunately."
	| pattern |
	pattern _ '*' , pName , '*'.  "match string"
	^ String streamContents:
	[:s |
	s nextPutAll: 'System categories...'; cr;
		print: (SystemOrganization categories select: [:n | pattern match: n]).
 
	s cr; cr; nextPutAll: 'Class names...'; cr;
		print: (Smalltalk classNames select: [:n | pattern match: n]).
 
	s cr; cr; nextPutAll: 'Class categories...'; cr;
		print: ((Smalltalk allClasses collect:
				[:c | (c organization categories select: [:n | pattern match: n]
						thenCollect: [:cat | c name , ' <' , cat , '>']) ,
					(c class organization categories select: [:n | pattern match: n]
						thenCollect: [:cat | c class name , ' <' , cat , '>'])])
				select: [:x | x size > 0]).
 
	s cr; cr; nextPutAll: 'Message names...'; cr;
		print: ((Smalltalk allClasses collect:
				[:c | (c selectors asArray select: [:n | pattern match: n]
						thenCollect: [:sel | c name , '>>' , sel]) ,
					(c class selectors asArray select: [:n | pattern match: n]
						thenCollect: [:sel | c name , '>>' , sel])])
				select: [:x | x size > 0]).
	]! !